Aminet 43/Aminet 43 (2001)(GTI - Schatztruhe)[!][Jun 2001].iso/Aminet/comm/tcp/TaskiSMS.lha/TaskiSMS_Install/Install_TaskiSMS

Text File | 2001-04-24 | 5KB | 211 lines

;
; TaskiSMS install script © by Pawel Filipczak
;
; $VER: TaskiSMS_Install 2.55 (18.04.2001) © Pawel Filipczak
;

(set TaskiSMS_version "2.55")

(set #about (cat "\n\nWelcome to TaskiSMS v" TaskiSMS_version "\n\nCopyright © 2000-2001 by\n\nPawel Filipczak\n<[e-mail]>\n\nhttp://taskisms.taski.com.pl/") )

(set #text_where "Where do you wish to install TaskiSMS. A directory called 'TaskiSMS' will be created if one is not there. If a copy of TaskiSMS is found it will be backed up.")
(set #text_exit (cat "\nTaskiSMS Install Complete!\n\n" ))
(set #text_toolbar (cat "Please select default toolbar which you want to use with TaskiSMS\n"))

(set #from_dir "InstallData")

; ********************** check for installer version

(set inst_version -1)

(if (exists "C:Installer" (noreq))
    (set inst_version (/ (getversion "C:Installer") 65536))
)

(if (= inst_version -1)
    (if (exists "SYS:Utilities/Installer" (noreq))
        (set inst_version (/ (getversion "SYS:Utilities/Installer") 65536))
    )
)

(if (= inst_version -1)
    (if (exists "SYS:Tools/Installer" (noreq))
        (set inst_version (/ (getversion "SYS:Tools/Installer") 65536))
    )
)

(if (= inst_version -1)
    (if (exists "SYS:Installer" (noreq))
        (set inst_version (/ (getversion "SYS:Installer") 65536))
    )
)

(if (= inst_version -1)
    (if (exists "Installer" (noreq))
        (set inst_version (/ (getversion "Installer") 65536))
    )
)

; ********************** about

(message #about)
(welcome)

;*********************** ask for install dir

(set TaskiSMS_dir    (askdir    (prompt #text_where)
                (help   @askdir-help)
                (default @default-dest)
            )
)

(set installdir (tackon TaskiSMS_dir "TaskiSMS"))


; ************************ check for older installation

(set    #old_exists 0)

(if (exists installdir)
  (


    (set tsms_vernum (getversion (tackon installdir "TaskiSMS")))
    (set tsms_ver (/ tsms_vernum 65536))
    (set tsms_rev (- tsms_vernum (* tsms_ver 65536)))

    (if (>= tsms_ver 2)
      (if (>= tsms_rev 50)
        (if (NOT (askbool (prompt "\nInstaller found TaskiSMS v2.5+ installed on your disk.\n\nDo you want to backup older version to TaskiSMS_old directory (click Backup) or update existing version with new files (click Update) ?") (help "") (choices "Update" "Backup")))
            ((rename installdir (tackon TaskiSMS_dir "TaskiSMS_old"))    (set    #old_exists 1))
        )
      ; else
        ((rename installdir (tackon TaskiSMS_dir "TaskiSMS_old"))    (set    #old_exists 1))
      )
; else
      ((rename installdir (tackon TaskiSMS_dir "TaskiSMS_old"))    (set    #old_exists 1))
    )


  )
)

; *********************** make TaskiSMS dir

(working "Making directories.")

(makedir installdir (infos))
(makedir (tackon installdir "Data"))
(makedir (tackon installdir "Data/Prefixes"))
(makedir (tackon installdir "Data/PlugIns"))
(makedir (tackon installdir "Data/Toolbars"))
(makedir (tackon installdir "Docs") (infos))
(makedir (tackon installdir "Docs/images"))

; *********************** copy files

; *** copy main program

(working "Copying main program.")

(copyfiles    (source (tackon #from_dir "TaskiSMS"))
        (dest    installdir)
        (nogauge)
        (infos)
)

; *** copy prefixes

(working "Copying prefixes.")

(foreach (tackon #from_dir "Data/Prefixes") "#?"

    (copyfiles    (source (tackon (tackon #from_dir "Data/Prefixes") @each-name))
            (dest    (tackon installdir "Data/Prefixes"))
            (nogauge)

    )
)

; *** copy plugins

(working "Copying plugins.")

(foreach (tackon #from_dir "Data/PlugIns") "#?"

    (copyfiles    (source (tackon (tackon #from_dir "Data/PlugIns") @each-name))
            (dest    (tackon installdir "Data/PlugIns"))
            (nogauge)
    )
)

; *** copy doc

(working "Copying documentation.")

(copyfiles    (source (tackon #from_dir "Docs/English.html"))
        (dest    (tackon installdir "Docs"))
        (nogauge)
        (infos)
)

(foreach (tackon #from_dir "Docs/images_eng") "#?"

    (copyfiles    (source (tackon (tackon #from_dir "Docs/images_eng") @each-name))
            (dest    (tackon installdir "Docs/images_eng"))
            (nogauge)
    )
)

; *** select and copy toolbar

(if (>= inst_version 44)
    (showmedia 'tb1' "InstallerData/Toolbars.iff" 'upper_center' 'none' 1)
)

(set toolbar    (askchoice (choices "MagicWB style by Andreas Kürzinger" "NewIcon style by Blase" "NewIcon style by Marc Savart" "Glowicon style by OliverTacke" "YAM style by Roman Patzner")
            (prompt #text_toolbar)
            (default 3)
            (help "help")
        )
)

(working "Copying toolbar.")

(if (= toolbar 0)    (set src_toolbar (tackon #from_dir "Toolbars/AndreasKuerzinger")))
(if (= toolbar 1)    (set src_toolbar (tackon #from_dir "Toolbars/Blase")))
(if (= toolbar 2)    (set src_toolbar (tackon #from_dir "Toolbars/MarcSavart")))
(if (= toolbar 3)    (set src_toolbar (tackon #from_dir "Toolbars/OliverTacke")))
(if (= toolbar 4)    (set src_toolbar (tackon #from_dir "Toolbars/YAM")))

(foreach src_toolbar "#?"
    (copyfiles    (source (tackon src_toolbar @each-name))
            (dest    (tackon installdir "Data/Toolbars"))
            (nogauge)
    )
)

(if (>= inst_version 44)
    (closemedia tb1)
)

(if (= #old_exists 1)

    (if (exists (tackon TaskiSMS_dir "TaskiSMS_old/Data/PhoneBook.dat"))

        (if (askbool (prompt "\nDo you want to copy PhoneBook from the previous installation of TaskiSMS?") (help "") (choices "Yes" "No"))

            (copyfiles    (source (tackon TaskiSMS_dir "TaskiSMS_old/Data/PhoneBook.dat"))
                    (dest    (tackon installdir "Data"))
                    (nogauge)
            )
        )

    )
)

(set @default-dest installdir)

(exit #text_exit)